# -*- coding: utf-8; mode: tcl; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- vim:fenc=utf-8:ft=tcl:et:sw=4:ts=4:sts=4

PortSystem          1.0
PortGroup           github 1.0
PortGroup           legacysupport 1.1

# strnlen
legacysupport.newest_darwin_requires_legacy 10

set rev             392ccfac4cdbaa282d50d6db2fba742c6b91fb55

github.setup        google angle $rev

# Major and minor version from src/common/angle_version.h
# Patch version using `git rev-list HEAD --count`
version             2.1.28226
revision            0
categories          graphics devel
platforms           {darwin >= 10}
license             BSD
maintainers         {makr @mohd-akram} {@barracuda156 macos-powerpc.org:barracuda} openmaintainer

description         OpenGL ES implementation
long_description    Cross-platform, conformant OpenGL ES implementation.

homepage            https://angleproject.org

github.tarball_from archive

# grep -E '/src/(build\.|testing|third_party/zlib)|jsoncpp_revision.:|SPIRV-(Headers|Tools)|Vulkan-Headers|astc-encoder@' DEPS
set astc_encoder    2319d9c4d4af53a7fc7c52985e264ce6e8a02a9b
set cr_build        6bb98d0865c859a763b390c583fe7670516ce08d
set cr_jsoncpp      f62d44704b4da6014aa231cfc116e7fd29617d2a
set cr_testing      224bb2459418e9a19aeb193a0df8935d2b685076
set cr_zlib         8b3aa8a1cd7585c0c4c67351481227b046a662a0
set jsoncpp         42e892d96e47b1f6e29844cc705e148ec4856448
set spirv_headers   daa093dd29aab8cbb6562b808370562f56e399fb
set spirv_tools     7db050bf022d203df651f8daa3e4542fdc2a8aea
set vk_headers      d2d8ded679e53c9f27c0c7a18750e661745886eb

master_sites-append https://github.com/gsource-mirror/chromium-src-build/archive/${cr_build}:chromium-build
distfiles-append    chromium-src-build-${cr_build}${extract.suffix}:chromium-build

master_sites-append https://github.com/gsource-mirror/chromium-src-testing/archive/${cr_testing}:chromium-testing
distfiles-append    chromium-src-testing-${cr_testing}${extract.suffix}:chromium-testing

master_sites-append https://github.com/gsource-mirror/chromium-src-third_party-jsoncpp/archive/${cr_jsoncpp}:chromium-jsoncpp
distfiles-append    chromium-src-third_party-jsoncpp-${cr_jsoncpp}${extract.suffix}:chromium-jsoncpp

master_sites-append https://github.com/gsource-mirror/chromium-src-third_party-zlib/archive/${cr_zlib}:chromium-zlib
distfiles-append    chromium-src-third_party-zlib-${cr_zlib}${extract.suffix}:chromium-zlib

master_sites-append https://github.com/KhronosGroup/SPIRV-Headers/archive/${spirv_headers}:spirv-headers
distfiles-append    SPIRV-Headers-${spirv_headers}${extract.suffix}:spirv-headers

master_sites-append https://github.com/KhronosGroup/SPIRV-Tools/archive/${spirv_tools}:spirv-tools
distfiles-append    SPIRV-Tools-${spirv_tools}${extract.suffix}:spirv-tools

master_sites-append https://github.com/KhronosGroup/Vulkan-Headers/archive/${vk_headers}:vulkan-headers
distfiles-append    Vulkan-Headers-${vk_headers}${extract.suffix}:vulkan-headers

master_sites-append https://github.com/ARM-software/astc-encoder/archive/${astc_encoder}:astc-encoder
distfiles-append    astc-encoder-${astc_encoder}${extract.suffix}:astc-encoder

master_sites-append https://github.com/open-source-parsers/jsoncpp/archive/${jsoncpp}:jsoncpp
distfiles-append    jsoncpp-${jsoncpp}${extract.suffix}:jsoncpp

checksums           ${distname}${extract.suffix} \
                    rmd160  b54a5ed075f948808e42cfa5eb52f89a9a3bf473 \
                    sha256  0a8b7d142f6639873cebfa13b9f5afbcc1dbfcf57d6266004a36ac85c53593a4 \
                    size    16977290 \
                    astc-encoder-${astc_encoder}${extract.suffix} \
                    rmd160  1c792cca8415346924640772699e6ffc2d3871f4 \
                    sha256  8b5068ef28a8db1cb354d89d9cefd19d43eddfc72c3468fce7ebb92b2431d4c4 \
                    size    36161899 \
                    chromium-src-build-${cr_build}${extract.suffix} \
                    rmd160  1f19f734ac38ba4b6188e2e370ff396606e85297 \
                    sha256  3ef10edc66f644541eb0c805032e2c7baa02ae452cbc40b3a5fa4ca5fbe2772e \
                    size    1787782 \
                    chromium-src-testing-${cr_testing}${extract.suffix} \
                    rmd160  22e13d70c3e42b78385235eb062274aabdf289ed \
                    sha256  418ea203c426add1bae5285277a363307b314b1c7a09cbb4da56eea82278cb7d \
                    size    2053152 \
                    chromium-src-third_party-jsoncpp-${cr_jsoncpp}${extract.suffix} \
                    rmd160  8611455ceb50dd821a942c3b10f2110c418fe182 \
                    sha256  7360eff9ce58208c68da260db23bdc29bbc00c769905af10aa45af0dd308aba4 \
                    size    4411 \
                    chromium-src-third_party-zlib-${cr_zlib}${extract.suffix} \
                    rmd160  5da06acf6cd8023c0742e4033f3e206ecec7ad4d \
                    sha256  3859b8acd39e67d7c6eb2e4008ffdfd0cd59f9332b320a71b416a6791b63ff7d \
                    size    1382863 \
                    jsoncpp-${jsoncpp}${extract.suffix} \
                    rmd160  2938aba554af493df2cc854497fa3a00d55521ee \
                    sha256  0b40e4598d68d3dbd8cab90b249e18f1363ecc694c38f727851f4db34b6887ec \
                    size    216350 \
                    SPIRV-Headers-${spirv_headers}${extract.suffix} \
                    rmd160  c41bc8809adc24529af6f132d39430a288eef090 \
                    sha256  ee4035b11e722e22a2fbee099798e25a89d0db013856d301f6c7701b4d123e6e \
                    size    569055 \
                    SPIRV-Tools-${spirv_tools}${extract.suffix} \
                    rmd160  860b1ba2b0eebc0c42eb3fa17f06663d9e8fc176 \
                    sha256  57e802916a228a843feb8c7dea5842a76f1a0c3dd1a820565e890ef9a3900045 \
                    size    3509819 \
                    Vulkan-Headers-${vk_headers}${extract.suffix} \
                    rmd160  e67111337a2ee1dc866bdd51c7549bf3de95abb9 \
                    sha256  deb2dad088821b0c7388478cb6e810e82c5cd62003249ec66c38a17438195413 \
                    size    3371391

post-extract {
    delete ${worksrcpath}/build
    move ${workpath}/chromium-src-build-${cr_build} ${worksrcpath}/build

    delete ${worksrcpath}/testing
    move ${workpath}/chromium-src-testing-${cr_testing} ${worksrcpath}/testing

    delete ${worksrcpath}/third_party/jsoncpp
    move ${workpath}/chromium-src-third_party-jsoncpp-${cr_jsoncpp} \
        ${worksrcpath}/third_party/jsoncpp

    delete ${worksrcpath}/third_party/zlib
    move ${workpath}/chromium-src-third_party-zlib-${cr_zlib} \
        ${worksrcpath}/third_party/zlib

    delete ${worksrcpath}/third_party/spirv-headers/src
    move ${workpath}/SPIRV-Headers-${spirv_headers} \
        ${worksrcpath}/third_party/spirv-headers/src

    delete ${worksrcpath}/third_party/spirv-tools/src
    move ${workpath}/SPIRV-Tools-${spirv_tools} \
        ${worksrcpath}/third_party/spirv-tools/src

    delete ${worksrcpath}/third_party/vulkan-headers/src
    move ${workpath}/Vulkan-Headers-${vk_headers} \
        ${worksrcpath}/third_party/vulkan-headers/src

    delete ${worksrcpath}/third_party/astc-encoder/src
    move ${workpath}/astc-encoder-${astc_encoder} \
        ${worksrcpath}/third_party/astc-encoder/src

    delete ${worksrcpath}/third_party/jsoncpp/source
    move ${workpath}/jsoncpp-${jsoncpp} \
        ${worksrcpath}/third_party/jsoncpp/source

    copy ${filespath}/gclient_args.gni ${worksrcpath}/build/config/
}

set py_ver          3.14
set py_ver_nodot    [string map {. {}} ${py_ver}]

depends_build       port:gn \
                    port:ninja \
                    port:python${py_ver_nodot} \
                    path:lib/pkgconfig/RapidJSON.pc:rapidjson

# Python only needed for scripts
depends_skip_archcheck-append \
                    python${py_ver_nodot}
configure.python    ${prefix}/bin/python${py_ver}

use_xcode           yes

# Upstream MacPorts patches:
patchfiles          patch-commit-id.diff \
                    patch-apple-toolchain.diff \
                    patch-src-common-platform.diff

# Our patches. These are needed / safe to use unconditionally,
# and sufficient to fix build on Catalina.
patchfiles-append   patch-debug.cpp.diff \
                    patch-apple_platform_utils.diff \
                    patch-SystemInfo_macos.mm.diff \
                    patch-build_config.h.diff \
                    patch-roll_aosp.sh.diff \
                    patch-driver_utils_mac.mm.diff \
                    patch-no-stupid-error-in-host_byteorder.diff

# May need to be broken down into general vs legacy part:
patchfiles-append   fix-broken-build-system.diff

# Misc fixes, exact threshold is unknown.
# Fixes bugs in build system, throws away rust includes (rust is not used for any archs,
# but gn includes its build spec files, which breaks powerpc build), recognizes powerpc,
# fixes OpenGL includes, fix wrong paths to /Developer contents.
if {${os.platform} eq "darwin" && ${os.major} < 19} {
    # Reverts regression from https://github.com/chromium/chromium/commit/365b67f3ec098a894a369945baa382824e1e7efc
    patchfiles-append \
                    fix-sdk-path.diff \
                    patch-FunctionsCGL.diff \
                    patch-fix-libtool.diff \
                    patch-IOSurfaceSurfaceCGL.cpp.diff \
                    patch-WindowSurfaceCGL.mm.diff \
                    patch-WindowSurfaceCGL-no-blit.diff \
                    patch-DisplayCGL.mm.diff \
                    patch-no-dsyms-and-strip.diff
}

if {${os.platform} eq "darwin" && ${os.major} < 15} {
    patchfiles-append \
                    no-metal-for-goodness-sake.patch
}

# No direct linking to CoreGraphics before 10.8:
if {${os.platform} eq "darwin" && ${os.major} < 12} {
    patchfiles-append \
                    patch-fix-frameworks.diff
}

# GL
if {${os.platform} eq "darwin" && ${os.major} < 11} {
    patchfiles-append \
                    patch-restore-legacy-desktop-gl.diff
}

# legacy-support, adjust if needed.
if {${os.platform} eq "darwin" && ${os.major} < 11} {
    patchfiles-append \
                    patch-legacysupport.diff
}

# Fix wrong struct size on ppc32:
if {${os.platform} eq "darwin" && ${configure.build_arch} eq "ppc"} {
    patchfiles-append \
                    patch-Uniform.h-fix-struct-size.diff
}

# Drop clangisms, fix 32-bit builds with gcc:
if {[string match *gcc* ${configure.compiler}]} {
    patchfiles-append \
                    fix-wrong-flags-for-gcc.diff \
                    patch-fix-threadId.diff \
                    patch-SoftLinking.h.diff \
                    patch-Context.cpp.diff \
                    patch-Display.cpp.diff \
                    patch-global_state.cpp.diff \
                    patch-fix-id-bug.diff

    # https://trac.macports.org/ticket/74110
    patchfiles-append \
                    patch-IntermNode.cpp.diff \
                    patch-IntermNode-overflow-guard.diff

    if {${configure.build_arch} in [list arm i386 ppc]} {
        patchfiles-append \
                    patch-libatomic.diff
    }
}

post-patch {
    reinplace "s|@COMMIT_POSITION@|[lindex [split ${version} .] 2]|" \
        ${worksrcpath}/src/commit_id.py

    fs-traverse f ${worksrcpath} {
        if {[string match *.py ${f}]} {
            reinplace -q "s|/usr/bin/python3|${configure.python}|" ${f}
            reinplace -q "s|/usr/bin/env python3|${configure.python}|" ${f}
        }
    }
    reinplace "s|@PYTHON@|${configure.python}|" ${worksrcpath}/scripts/roll_aosp.sh
    reinplace "s|exec python3|exec ${configure.python}|" ${worksrcpath}/build/gn_editor
    reinplace "s|/usr/bin/env python3|${configure.python}|" ${worksrcpath}/build/util/ide_query

    if {${os.platform} eq "darwin" && ${os.major} < 11} {
        reinplace "s|@PREFIX@|${prefix}|g" ${worksrcpath}/build/config/compiler/BUILD.gn
    }
}

compiler.cxx_standard   2020

# avoid conflict with installed zlib
compiler.limit_flags    yes

if {${macosx_deployment_target} eq ""} {
    # Uses IOSurface
    set macosx_deployment_target 10.6
}

configure.cmd       gn
configure.pre_args  gen out
configure.args      --args='\
                    angle_build_tests=false \
                    angle_enable_metal=false \
                    angle_enable_vulkan=false \
                    angle_enable_wgpu=false \
                    enable_rust=false \
                    fatal_linker_warnings=false \
                    is_clang=false \
                    is_official_build=true \
                    install_prefix=\"${destroot}${prefix}\" \
                    mac_sdk_min=\"${macosx_deployment_target}\" \
                    mac_deployment_target=\"${macosx_deployment_target}\" \
                    mac_min_system_version=\"${macosx_deployment_target}\" \
                    treat_warnings_as_errors=false \
                    use_custom_libcxx=false \
                    use_system_xcode=true' \
                    --script-executable=${configure.python}
configure.post_args -v

# Needed, otherwise the build picks system zlib and everything breaks:
configure.cppflags

if {${os.platform} eq "darwin" && ${os.major} < 19} {
    configure.cppflags-append \
                    -DTARGET_OS_MACCATALYST=0 \
                    -DMTLGPUFamilyMac2=2002
}
configure.cxx       ${configure.cxx} {*}${configure.cppflags}

build.cmd           ninja
build.pre_args      -C out
build.post_args     -v
build.env           ANGLE_UPSTREAM_HASH=[string range $rev 0 11]

destroot.cmd        ninja
destroot.pre_args   -C out
destroot.post_args  -v
destroot.destdir
destroot.target     install_angle

post-destroot {
    copy ${worksrcpath}/out/angle_shader_translator ${destroot}${prefix}/bin/

    reinplace "s|^prefix=.*$|prefix=${prefix}|" \
        {*}[glob ${destroot}${prefix}/lib/pkgconfig/*.pc]

    delete \
        ${destroot}${prefix}/include/CL \
        ${destroot}${prefix}/include/GLX \
        ${destroot}${prefix}/include/WGL \
        ${destroot}${prefix}/include/GLSLANG \
        ${destroot}${prefix}/include/vulkan \
        ${destroot}${prefix}/include/platform \
        {*}[glob ${destroot}${prefix}/include/*.h] \
        {*}[glob ${destroot}${prefix}/include/*/README.md] \
        {*}[glob ${destroot}${prefix}/include/*/.clang-format]

    platform darwin {
        foreach f [glob -tails -directory ${destroot} ${prefix}/lib/*.dylib] {
            system "install_name_tool -id /$f ${destroot}/$f"
        }

        system "install_name_tool -change ./libGLESv2.dylib \
            ${prefix}/lib/libGLESv2.dylib \
            ${destroot}${prefix}/lib/libGLESv1_CM.dylib"
    }
}

livecheck.url       https://chromiumdash.appspot.com/fetch_releases?channel=Stable&platform=Mac
livecheck.type      regex
livecheck.regex     {"angle":"([0-9a-f]+)"}
livecheck.version   $rev
