$MATRICES << EOM
# A garbage line at the beginning that is not an index

# set1
0	0.314	0.628
2	3.06	1.51
8	1.974	1.03


# set2
0	0.314	0.628
20	3.06	2.01
80	1.974	1.03


# set3
0	0.314	0.628
2	1.06	3.01
8	2.974	4.03
EOM

set palette cubehelix
unset colorbox
set cbrange [1:3.6]
set key box opaque samplen 0
set xrange [] noextend
set yrange [] noextend

set multiplot layout 2,2 margins char 3,3,2,4 title "{/:Bold Data file contains labeled ascii matrices}

set title "Y range should be the same"
plot '$MATRICES' nonuniform matrix i "set3" w image title "index 'set3'"
set title "colors should be the same"
plot '$MATRICES' nonuniform matrix i "set2" w image title "index 'set2'"
unset title
plot '$MATRICES' nonuniform matrix i 0 w image title "index 0"
plot '$MATRICES' nonuniform matrix i 1 w image title "index 1"

unset multiplot

pause -1  "Hit return to continue"

reset
